/* UTF-8
 *
 * © Jacques Duma
 * 14 mai 2009
 *
 * Tir à la Cible avec Trajectoire Parabolique
 */


//====================================================================
// BoutonInitJeu est un bouton-bascule en fonction de initEnCours
//====================================================================
// === BoutonInitJeu : DESSIN (appelée dans draw) ===
void drawBoutonInitJeu() {
  color face = color(127, 0, 0);
  color fond = color(0, 255, 255);
  // on inverse les couleurs lors du survol du bouton par la souris
  if (mouseInBoutonInitJeu()) {
    fond = negatif(fond);
    face = negatif(face);
  }
  // le rectangle du BoutonInitJeu
  stroke(face);
  fill(fond);
  rect(width - 97, 5, 91, 16);
  textFont(policeStandard);
  textAlign(CENTER, TOP);
  fill(face);
  // le texte du BoutonInitJeu bascule en fonction de initEnCours
  if (initEnCours)
    // si initEnCours le bouton permet de lancer la balle
    text("Lancer la Balle", width - 51, 9);
  else
    // sinon le bouton permet de revenir à l'initialisation
    text(bravo ? "Rejouer" : "Corriger le Tir", width - 51, 8);
}

// === BoutonInitJeu : EVENEMENT (appelé dans mouseReleased) ============
boolean mouseInBoutonInitJeu() {
  return mouseX >= width - 97 && mouseX <= width - 5 && mouseY >= 3  && mouseY <= 20;
}

// === BoutonInitJeu : EVENEMENT (appelé dans mouseReleased) ============
void mouseReleasedBoutonInitJeu() {
  if (initEnCours) {
    // bascule en mode JEU
    initEnCours = false;
  }
  else {
    // bascule en mode INITIALISATION
    initEnCours = true;
    // en fin de jeu
    if (bravo) {
      // Si on vient de toucher la cible, on en place une nouvelle cible
      nouvelleCible();
      bravo=false;
    }
    // activation du JEU
    raz();
  }
  effacerTraces();
  jeuActif = true;
}
//====================================================================